로보밥

수개월전 실내 테스트까지만 해왔던 기상측정 트위터 로봇을 중요한 프로젝트에 활용하신다는 분께 양도 후 새로 구하지 못해서 기다려오다 최근 다시 입수하게되었습니다.  ^^. 드디어 기다려왔던 실외 설치 후 실제 운영테스트를 해보게되었습니다.  눈도 오고 꽁꽁 얼어붙는 날씨인데도 아직 멀쩡히 작동하고 있습니다.  기존 스토리는 관련글 링크를 참고하시기 바랍니다.

이번엔 실외 설치를 위해 이더넷하우징 케이스에 모든 기능을 넣어버리는 시도를 하였습니다.  아두이노 보드 + 이더넷 쉴드를 이더넷일체형 아두이노보드로 변경한데 이어 관련 부품을 작은 케이스안에 넣고 UTP 케이블 단자만으로 결합이 되도록 구성하였습니다.  어떻게 하는지는 사진을 보시면 참고가 되실 것 같습니다.

우선은 관련 동영상과 이미지를 올려드리고,  상세한 부분은 조금씩 추가하도록 하겠습니다.

실외 설치 후 작동상태와 트위터봇의 외부 및 내부 이미지

관련글 링크
1.기상측정 기구 + 아두이노로 기상대 만들어요 (Arduino + Weather Sensor Assembly )

2.트위터(Twitter)에 자동 포스팅하는 기상관측 로봇

3.기상측정 트위터 로봇 - 실외 설치편 (현재 글)

RGB LED는 오색 찬란 무지개 색상을 자유롭게 표현할 수 있는 재료입니다. 하지만 여러개를 사용하기위해서는 회로나 프로그래밍이 복잡해져서 직접 제작하기엔 부담이 큽니다.  이를 위해 지금 소개해 드릴 20개단위로 LED 체인으로 구성된 제품을 사용하면 손쉽게 독립제어되는 다수의 RGB LED 사용이 가능해집니다.  관련제품 사용법을 알려드리겠습니다.

손쉽게 사용가능하도록 라이브러리와 아두이노 예제 소스가 제공됩니다.  한줄 만 수정하면 그대로 이용 가능합니다.
관련 동영상을 보신 후, 아래의 상세과정을 참고하시기 바랍니다. ^^.

- 이하 사용법 안내 -

라이브러리 설치 방법
1.압축해제후,
2. WS2801.cpp 등의 파일이 들어있는 폴더를 아두이노 설치폴더의 Libraries 폴더에 복사후,
3. 폴더명을 WS2801으로 변경하시기 바랍니다.
4. 아두이노 스케치를 재 시작합니다.

예제소스 및 수정
소스코드 폴더를 보시면 Example 폴더에 예제파일이 있습니다.
소스코드 상단주석과 설명을 보시면 설명이 되어있습니다.
해당 소스코드에서 통신용(data선, clock선)으로 사용되는 핀 2개의 번호를 확인하셔서 해당핀에 케이블을 연결하시면됩니다.
본 제품은 모듈(pixel)의 수가 20개이므로, 기본 25개로 되어있는 부분을 20으로 수정하시면 됩니다.

 int dataPin = 2;   // 데이타 전송용 데이타 핀번호 ( 다른핀으로 변경 가능)
int clockPin = 3; // 데이타 전송시 클럭용 핀번호 ( 다른핀으로 변경 가능)

WS2801 strip = WS2801(20, dataPin, clockPin);   //LED모듈 개수 25를 20으로 변경한 예

즉,  위 코드 한줄만 바꿔주시면 끝입니다.   20개 모듈체인 2세트를 연결시엔 40으로 변경해야겠죠

케이블 단자 안내 (시작 모듈 기준)

    (주의. 색상은 시작모듈 기준입니다, 두번째 모듈부터는 시작모듈 기준 배치와 동일하며 케이블 색상은 바뀔수 있으니 잘라서 사용시 주의하시기 바랍니다.아래 그림 참조)

시작모듈/끝모듈 구분법
어디가 시작이고 어디가 끝인지를 구분하시기 위해 모듈 밑면에 있는 화살표를 참고하시면 됩니다.
시작모듈에 케이블을 연결하시면 됩니다.

관련제품

RGB LED 독립 색상 제어 20개 연결형
정전압 아답터 5V 2000mA SMPS
점퍼 와이어 M/F 10개형
아두이노 UNO
브레드보드 점퍼 케이블 ( Solderless Breadboard Jumper Wire 75 pcs )
브레드보드 호환형 DC 잭 아답터 (DC Barrel Jack Adapter - Breadboard Compatible)

아두이노와  GND,  CLOCK, DATA  핀  3개만 연결해주시면 됩니다.

아두이노와 Clock, Data 신호가 연결되는 시작모듈 을 찾기 위해서 모듈 뒷면을 보시면 화살표시가 있습니다.

Male/Female 점퍼 케이블을 이용하시면 케이블 작업이 손쉬워 집니다.

20개 묶음을 2세트(총 40개) 연결한 장면입니다. (단, 전원은 힘 좋은 녀석 사용이 필수겠죠 ^^.)

Tip. 기본 20개 체인형 제품이지만, 2세트를 묶어 40개를 연결하거나  1개나 N개 단위로 잘라서 사용도 가능한 .... 기특한 녀석입니다.

공식 아두이노의 최신 표준보드 UNO의 R3버전이 나왔습니다.(2011년 12월)

보통 UNO 하면 마이크로콘트롤러 칩 타입에따라 SMD타입과 DIP타입 두 가지가 있었지만, 이제 형제가 더 많아졌네요, 아직 R3버전의 SMD타입은 공개되지 않은것 같으므로 현재 아래와 같은 3종류의 UNO가 있습니다.
UNO R2 DIP형
UNO R2 SMD형
UNO R3 DIP형


[]R2와 R3의 차이점 요약
일단, R2나 R3나 주 마이크로콘트롤러는 ATMega328 칩을 사용하므로
프로그래밍 가능용량이나 제어핀의 개수와 사용방법이 모두 동일합니다.
다만, USB 인터페이스칩이 변경되었고 헤더핀의 개수가 3개 추가되었습니다.
그렇다고 기본성능이 업그레이드 된것도 아니어서 기존 R2와 동일하게 사용하시면 됩니다.


[]변경된것
1.USB 인터페이스칩이 atmega8u2에서 atmega16u2로 변경됨:
단, (주콘트롤러칩은 R2와 동일하므로) 이것이 아두이노 프로그래밍 가능용량의 증가를 의미하지는 않습니다.
단, USB제어칩을 개조하여 사용할 경우 유용할수있음.

2. 노출 헤더 구멍이 3+1개 추가됨:
AREF핀옆에 I2C 헤더소켓 2구가 추가되었음.
단, 여분의 i2c핀이 새로 추가된것이 아니고 기존의 i2c핀(Analog 4번 5번)에 중복 연결된것입니다.
(차후 Mega시리즈 같은 다른 아두이노 보드와의 쉴드 호환성을 위한 고려로 여겨짐)
더불어 IOREF 노출 헤더소켓 1구가 Reset핀 옆에 추가되었습니다.
(이는 쉴드에서 보드의 작동전원을 파악하는 용도로 사용될 것으로 여겨짐)
물론 이핀도 power pin의 노출 헤더출구 1개가 추가된 것일뿐 없던 제어핀이 새로추가된것은 아닙니다.
나머지 1 구는 미사용 예비용이라네요;;

[]변경되지 않은것
1. 모든 UNO(R2 R3)는 프로세서 속도 및 기억 용량이 동일합니다.
2. 제어가능한 핀의 개수도 동일합니다.
3. 보드 크기와 모양도 그대로 유지
4. 쉴드호환성 동일( R1 R2용 쉴드를 R3에서도 그대로 호환사용가능)
5. 드라이버도 동일
6. 업로딩속도도 동일 (스케치에서 보드 종류를 UNO로 선택하면됩니다.)

참고원문링크:

http://www.ladyada.net/library/arduino/unofaq.html

이하 영문 제품자료

Description: This is the new Arduino Uno R3. In addition to all the features of the previous board, the Uno now uses an ATmega16U2 instead of the 8U2 found on the Uno (or the FTDI found on previous generations). This allows for faster transfer rates and more memory. No drivers needed for Linux or Mac (inf file for Windows is needed and included in the Arduino IDE), and the ability to have the Uno show up as a keyboard, mouse, joystick, etc.

The Uno R3 also adds SDA and SCL pins next to the AREF. In addition, there are two new pins placed near the RESET pin. One is the IOREF that allow the shields to adapt to the voltage provided from the board. The other is a not connected and is reserved for future purposes. The Uno R3 works with all existing shields but can adapt to new shields which use these additional pins.

Arduino is an open-source physical computing platform based on a simple i/o board and a development environment that implements the Processing/Wiring language. Arduino can be used to develop stand-alone interactive objects or can be connected to software on your computer (e.g. Flash, Processing, MaxMSP). The open-source IDE can be downloaded for free (currently for Mac OS X, Windows, and Linux).

Features:

• ATmega328 microcontroller
• Input voltage - 7-12V
• 14 Digital I/O Pins (6 PWM outputs)
• 6 Analog Inputs
• 32k Flash Memory
• 16Mhz Clock Speed

Documents:

• Schematic
• Eagle Files
• Product Page
• Arduino IDE Download

이미 소개해 드렸던 촬영된 이미지를 JPEG 포멧으로 압축하여 시리얼통신으로 전송해주는 카메라를 PC와 직접 연결하여 테스트해봤습니다.  시리얼 통신으로 촬영된 데이타를 전송해주므로  시리얼통신을 지원하는 모든 기기에 연결 가능합니다. 게다가 JPEG 이미지 포멧으로 압축하여 전송을 해주므로 저장만 해주면 PC에서도 그대로 확인이 가능해집니다.
본 동영상에서는 USB to 시리얼 변환기를 통해 PC와 연결한 뒤,  기본 제공되는 PC 용 테스트 프로그램을 이용하여  실시간 이미지 전송과 Single Shot(한장촬영) 기능을 테스트 및 해상도와 전송속도 조절기능도 사용해봤습니다. 

PC와 연결 구성

   PC USB포트<-> USB 케이블 <-> USB to Serial FTDI 변환기 <-> TTL Serial JPEG Camera

관련제품
 JPEG 시리얼통신 카메라
 USB to Serial 변환기 5V형

관련글 링크
 DIY 자작 휴대형 디지탈 카메라 만들기

오늘은 울트라 하이테크놀로지의 결합체인 디지탈 카메라를 만들어봤습니다.  "정말 피눈물나는 노력을 통해 완성한 나만의 아두이노 호환 똑딱이입니다." 라고 말씀드리면 거짓말이고요,  사실 제가 한 일이라곤 촬영된 이미지를 JPEG 포멧으로 시리얼통신을 통해 전송해주는 카메라와 이값을 수신하여 microSD메모리에 저장해주는 역활을 해주는 JPEG Trigger 아두이노 호환보드를 단순히 조립해주고 버튼한개 달랑 단것이 전부입니다.  아, 그리고 휴대용 카메라의 역활을 다할 수 있도록 3.7V Lipo충전지도 장착해줬습니다.  성능은 최신 카메라에 비길수 없겠지만 그래도 좋은건 센서연동 및 자유로운 제어가 가능한 아두이노 호환형 디지탈 카메라 시스템이라는 점입니다. 

시리얼통신 JPEG 카메라가 무엇인가?
시중에서 많이 구경할 수 있는 카메라들과 달리 촬영된 이미지를 JPEG 이미지 포멧으로 압축하여 시리얼 통신(TTL 레벨)으로 전송해주는 특수 카메라입니다.  즉, 시리얼 통신이 가능한 모든 기기에서 압축된 디지탈 이미지 데이타를 수신할 수 있습니다.(일반적인 video 신호 출력도 지원)  PC의 경우엔 FTDI USB시리얼 변환보드를 경유하여 카메라를 제어하고 이미지를 수신해 볼 수 있습니다. (

관련글 - 시리얼통신 카메라 PC연결하기 

)
그리고 무엇보다도 아두이노같은 8bit 저속 MCU 보드들에서도 시리얼통신으로 촬영된 이미지를 수신할 수 있게 되어 유용한 카메라입니다. 물론 압축된 이미지(JPG) 데이타라도 아두이노에서 실시간 처리를하는 것은 무리가 있습니다.  하지만 데이타를 SD메모리에 저장하고 참고하는 형태의 응용이라면 충분히 제 역활을 할수 있게되는데요,  이 역활을 하는 전용 보드(JPEG Trigger)가 있어 함께 사용하면 손쉽게 디지탈 카메라 기능 구현이 가능해집니다.

JPEG Trigger 보드
본 제품은 JPEG Camera와 짝을 이뤄 사용하도록 최적화된 아두이노 호환 보드이지만 몇가지 특수 기능을 갖쳐서 프로그램을 바꿔서 다른 용도로 사용하는것도 좋을 것 같습니다.   JPEG 이미지 저장용 microSD 메모리 인터페이스와   1V~ 5V 사이의 전원을 입력해주면 내장된 승압회로를 통해 5V전원으로 작동되도록 설계되어 건전지(1.5V or 3V)나 Lipo(3.7V) 충전지 하나만으로 작동이 가능합니다.  야호!  더불어 총 6개의 범용 IO핀( 아두이노 D2,D3,D4,A0,A1,A2) 홀이 제공되어 트리거(Trigger, 셔터눌러주기) 용도 및 기타 IO기능으로 사용이 가능합니다. 


오픈 소스 하드웨어
공개된 소스코드와 라이브러리를 설치해주면(이미 프로그램되어 있음) 원하는 방식으로 카메라 구현이 가능하므로 응용범위가 무궁무진해 집니다.

사진. 초간단 디지탈 카메라 구현 연결이미지
카메라 + 보드 + Lipo충전지 + 버튼 을 연결해주기만 하면 프로그래밍 없이도 바로 작동합니다.

동영상. 결합상태 확인 및 사진촬영 테스트

동영상 내용 소개
보드, 카메라, 충전지, 버튼이 연결된게 보입니다. 스위치를 켜주면 상태점검 후 상태 LED가 켜집니다.  이게 안켜지거나 깜빡거리면 카메라나 메모리에 문제가 있는것입니다.   초기상태의 경우  D2,D3,D4 버튼중의 하나를 GND에 연결하는 순간 카메라 셔터가 작동(촬영)되고 JPEG으로 압축된 이미지가 시리얼 통신으로 보드에 전달되고 이 정보가 SD메모리에 저장됩니다. 마침 네모로봇 군이 옆에 있어 버튼을 눌러 촬영을 해봤습니다.  이미지가 저장되는 중에 상태 LED가 깜빡거리는게 보입니다.  저장이 완료되면 상태 LED가 다시 켜집니다.  저장된 이미지는 PC에 연결하여 (변환과정 없이) 볼 수 있습니다.  (단, 초기 프로그램된 상태에선 확장자가 txt로 저장이되는 문제가 있어서 이를 PC에서 jpg 확장자로 변환해야 볼 수 있습니다. 신규 소스로 업로드하시면 이문제는 해결됩니다.)

사진. 촬영된 이미지 예



카메라와 보드 연결
JPEG카메라 <-> JPEG트리거보드
VCC -- 5V
GND -- GND
TXD -- D5(Rx)   주의. 카메라측 송신(Tx)단자가 트리거보드 측 수신(Rx)에 (교차)연결됩니다.
RXD -- D6(Tx)   주의. 카메라측 수신(Rx)단자와 트리거보드 측 송신(Tx)에 (교차)연결됩니다.
TV(미연결)  일반적인 video 신호출력선입니다. 본 예제에서는 사용안함.

전원
배터리 단자에 3.7V 정도의 Lipo충전지를 연결하여 사용하거나,
배터리 단자 옆에있는  GND와 1~5V 핀에   1~5V 전원을 연결해줍니다.
(입력된 전원은 5V승압회로를 통해 5V로 승압되어 공급되게됩니다.)
(FTDI USB시리얼 보드 연결시엔 usb 전원이 상시 연결됩니다.)

보드테스트
(카메라 및 메모리)아무것도 장착하지 않은상태에서
스위치 off상태에서 Lipo단자에 Lipo배터리 연결후, 스위치 on하고 몇초후 LED가 깜빡거려야함.


스위치 기능
배터리 입력전원을 승압회로에 연결여부를 선택해준다.(회로도를 꼭 참고하세요)
배터리 사용시 보드 ON/OFF 기능으로 사용됩니다.
(FTDI USB시리얼 보드 연결시엔 usb 전원이 상시 연결됩니다.)

사용법
카메라와 FAT 포멧된 메모리를 장착후 전원을 켜주면 LED가 ON된다.
메모리가 없거나 포멧상태 문제등으로 초기화가 안되면 LED는 깜빡인다.
카메라가 연결되지않은경우 LED가 안켜진다.
(단, 상태LED 모드는 펌웨어에 따라 다를수있으므로 해당 소스 상단 주석을 확인바랍니다.)

입출력핀
카메라 촬영신호를 받거나 I/O용으로 아래의 6개핀을 사용할 수 있습니다.
아두이노 디지탈핀 D2,D3,D4와
아두이노 아날로그핀 A0,A1,A2를 입출력
보드에는 손쉽게 전원활용을 할수있도록 각 입출력핀마다 GND,5V 홀(구멍)이 함께 있어서
총 18개의 구멍이 있습니다. 이때 GND, 5V 구멍이 안쪽에 있고 바깥쪽이 D2,D3,D4,A0,A1,A2 핀이므로 주의바랍니다.



카메라 촬영법
초기 제공되는 펌웨어(소스참조)의 경우
D2,D3,D4 핀을 GND에 연결하거나 (내부 Pullup되므로 별도 저항없어도 됩니다)
A0,A1,A2 핀을 5V에 연결하는 순간 카메라 촬영이 되고,이미지가 메모리에 저장됩니다.
이때 LED가 깜빡거리고, 저장이 끝날때까지는 재촬영이 안됩니다.


저장된 JPEG이미지
초기 제공되는 펌웨어의 경우,
저장된 이미지는 001.TXT 와 같이 확장자가 TXT로 저장되는 문제가있으며 이를 PC에서 JPG로 변경하셔야 이미지 확인이 가능합니다. 하지만 새로 제공되는 소스코드로 재프로그래밍 하시면 JPG확장자로 저장되므로 꼭 업그레이드 하시기 바랍니다.


주의사항:
보드가 켜있는 상태에서 메모리카드를 뽑지 마세요! 메모리 상태 및 보드 펌웨어 상태가 손상될 수 있습니다.
이경우 보드 펌웨어를 재프로그래밍하고 메모리를 재 포맷해야할 수 있습니다.

이번엔 기상측정기구와 이더넷 쉴드가 장착된 아두이노(Arduino)로 기상관측 자료를 트위터(Twitter)에 자동으로 올려주는 기특한 녀석을 소개시켜 드리겠습니다. 제법 시스템이라 불릴 만한 구성입니다.  바람의 방향과 속도 및 강수량을 측정할 수 있는 기상관측 기구로 부터 측정된 값을 모니터링하고 이를 곧바로 인터넷을 통해 트위터(twitter)에 올리는 것입니다.  기상 데이타 측정용으로 사용된

가상 관측기기에 대해선 관련글 링크

를 참고하시기 바랍니다.

본 글을 이해하기위해 필요한 사전지식:  기본적인 아두이노 스케치 개발환경 사용법, 라이브러리 설치법, 이더넷쉴드 사용경험, 트위터의 기본적인 이해, 기상관측 기구 센싱방법 등


트위터?
트위터(Twitter)가 뭔지는 저보다 여러분이 더 잘 알고 계실것 같습니다.  제경우 트위터 사용법도 잘 모릅니다만 순서가 뒤바껴서 트위터 포스팅해주는 로봇을 먼저 만들게 되었습니다;;;   이글을 이해하시려면 일단 트위터에 가입하셔서 트위(Tweet) 하나를 올려보시면 됩니다.

아두이노 + 이더넷 쉴드
썰렁한 아두이노(Arduino) 보드에 이더넷 쉴드를 얹으면 인터넷을 통해 전세계와 의사소통이 가능합니다. 더불어 천재적이면서 친절하기까지 하신 분들이 아두이노로 트위터에 메시지를 보내는 예제와 라이브러리를 공개해 주셨으므로 저와 여러분들은 손쉽게 엄청난?;; 시스템 구현을 할 수 있는 상황입니다.  이더넷 쉴드 사용 경험이 없으신 분들은 우선 공개된 정보와 아두이노 스케치IDE에 포한된 기본 예제를 참고하시기 바랍니다.


아두이노 + 이더넷 쉴드의 한계
이더넷 쉴드를 장착하면 아두이노 보드로 정보서비스를 제공해주는 서버 역활을 할 수 있습니다.  외부 접속이 가능한 IP주소를 사용한다면 전세계의 인터넷 접속가능 기기를 통해 정보를 제공받을 수 있습니다.  하지만 동시 접속수 제한이나 퍼포먼스 문제로 원할한 서비스 제공에는 한계가 있습니다. 이때문에 아두이노를 데이타 센싱이 용이한 현장에 설치 후 취합한 데이타를 웹서비스를 담당하는 PC급 서버로 전달하여 제대로된 웹서비스 환경에 응용하는 것이 더 안정적인 방법일 수 있습니다.

이때 손쉽게 사용가능한 서비스가 HTTP Client입니다. 즉, 아두이노는 웹클라이언트로써 웹서버에 필요할 때만 접속하여 데이타를 송/수신 하는 방식입니다.    이더넷 라이브러리와 함께 제공되는 기본예제(WebClient)를 조금만 수정하면 활용이 가능합니다.  IP주소로 접속이 가능한 웹서버가 있는경우 추천할만한 방법입니다.  다만 문제는 기본 이더넷 쉴드 라이브러리를 이용한 Web Client 로는 domain name ( http://robobob.co.kr 같은) 을 통한 서버 접속이 안되고  123.123.123.123  같은 숫자형식의 ip를 이용한 접속만 가능하다는 점입니다.  예전에는 ip주로를 통한 접속 주소를 지원하는 웹호스팅 서비스가 있었지만 요즘엔 이를 지원하지 않는곳이 대부분인것 같습니다. 때문에 특정 웹호스팅 서비스나 단독 호스팅서비스를 사용하지 않으면 Web Client 사용한 접속이 불가한 상황입니다.  (일반적인 URL 주소를 통한 아두이노의 HTTP Client 접속 방법을 아시는 분은 안내 부탁드립니다.)

트위터 활용
HTTP Client 활용에 문제가 있으나 오히려 더 효과적일 수 있는 데이타 공유 방법이 있으니 바로 트위터입니다. 짧은 단문을 포스팅하면 수많은 팔로워에게 전달되는 효과적인 데이타 공유시스템을 활용하는 것입니다. 게다가 요즘 대세인 스마트폰에서도 손쉽게 접근이 가능한 최신병기입니다. 그런데 방법이 어렵냐고요???  제가 해보니 생각보다 매우 간단했습니다.   트위터 엡 개발을 위해 API니 뭐니 습득하고 복잡한 절차가 필요한지 알았는데요, 그게 아니고 그냥 사용만 하면 되네요...


트위터 포스팅 방법
방법은 요 사이트에 잘 요약되어있습니다.

http://arduino-tweet.appspot.com/

별 설명이 필요없습니다만, 정리하자면 아래와 같습니다.
1. 트위터 앱(O Auth)에 접속하여 승인을 해주면 복잡한 문자열로 된 토큰 정보가 생성됩니다. 이 값을 복사하여 잘 보관합니다.
2. 관련 라이브러리들을 설치해줍니다. 두군데 정도 접속하여 파일을 받아서 아두이노 library 폴더에 적절한 이름으로 복사합니다.
3. 예제소스를 실행해봅니다.
   위 라이브러리를 제대로 설치하면 스케치 IDE  Examples 리스트에 Twitter가 생깁니다.
   File menu > Examples > Twitter > SimplePost 예제를 선택해줍니다.

이더넷 쉴드 사용시 수정해주는  ip주소와 네트웍정보 몇개만 수정해주시고 추가로  "YOUR-TOKEN-HERE" 부분을  위에서 발급받은 토큰값으로 대체해 주면 준비 끝~ 입니다.
이젠 잘 전송되는지 확인을 위해 시리얼 모니터링 창을 열고 속도(9600)를 맞쳐줍니다.

SimplePost 예제 소스 내용보기

#if defined(ARDUINO) && ARDUINO > 18   // Arduino 0019 or later
#include <SPI.h>
#endif
#include <Ethernet.h>
#include <EthernetDNS.h>
#include <Twitter.h>

// Ethernet Shield Settings
// 쉴드 밑면에 있는 mac 정보를 적어줍니다. 쉴드가 하나인경우 안바꿔도 무방
byte mac[] = { 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED }; 


// substitute an address on your own network here
byte ip[] = { 192, 168, 2, 250 };   //공유기에서 사용되지않는 IP값을 지정

// Your Token to Tweet (get it from http://arduino-tweet.appspot.com/)
Twitter twitter("YOUR-TOKEN-HERE");   // 발급받은 토큰값을 이곳에 붙여넣으세요

// Message to post
char msg[] = "Hello, World! I'm Arduino!";   // 한글 전송도 가능합니다!

void setup()
{
  delay(1000);
  Ethernet.begin(mac, ip);
  Serial.begin(9600);
 
  Serial.println("connecting ...");
//부팅시 1회 포스팅 시도합니다.
  if (twitter.post(msg)) {
    // Specify &Serial to output received response to Serial.
    // If no output is required, you can just omit the argument, e.g.
    // int status = twitter.wait();
    int status = twitter.wait(&Serial);
    if (status == 200) {
      Serial.println("OK.");
    } else {
      Serial.print("failed : code ");
      Serial.println(status);
    }
  } else {
    Serial.println("connection failed.");
  }
}

void loop()
{ //아무것도 안합니다. 
}

SimplePost 예제 소개
예제로 사용된 소스에는 아두이노가 부팅할때마다 1회 포스팅을 하고, 포스팅 될때마다 결과 상태를 시리얼 통신으로 전달해 줍니다. (참고로 시리얼 창 새로 열거나 통신속도를 변경하여도 아두이노가 재부팅이되어 새로 포스팅을 시도합니다.)
결과가 Okay로 뜬다면 잠시 후 여러분의 트위터 페이지에 새 트윗이 올라온것이 보일 겁니다.
Okay 외의 오류 메시지를 잘 살펴보시면 디버깅에 도움이 됩니다.

포스팅 시도후 오류메시지가 뜨는 경우가 종종 있는데요  제가 발견한 주요 오류 내용은 아래와 같습니다.
1. 동일한 내용을 중복하여 전송한 경우: 이경우 중복 전송된 값은 무시됩니다.
2. 트윗 작성 한계치 초과 :  시스템 보호를 위해 일정 시간당 한정된 개수의 트윗만 허용됩니다.   이 수량을 초과시 일정기간 동안 트위 작성이 불가하며 일정 시간이 지난뒤에 다시 작성이 가능해집니다.   가령  수십초에 한번씩 계속 트윗을 하신다면 얼마지나지 않아 트윗 등록이 거부될 겁니다.   아래의 예제에서는 1시간에 1회 트윗을 발신하게됩니다.




드디어 트위터 기상로봇

이제 포스팅될 정보를 여러분의 용도에 맞게 잘 구성해주시면 여러분만의 활용도 만빵인 트위터 포스팅 봇이 완성됩니다.
제 경우 이미 소개드렸었던 기상측정기기를 활용하여 1시간마다 기상데이타를 측정하여 전송해주는 예제를 만들어봤습니다.
실제 포스팅된 내용들을 아래의 페이지에서 확인 가능합니다.

로보밥 기상측정 로봇 트위터 메시지 보러가기 :  

http://twitter.com/artrobot_bot1

한동안 실내 테스트만 하다가 2012년 1월 29일 현재,  옥외 설치하여 운영중입니다.  위 링크에 가보시면 실제 기상자료를 참고하실 수 있습니다. (경기도 수원시 오목천동)

위에서 트윗된 메시지의 포스팅 시간을 보시면 (오차가 1분도 안되네요^^.)1시간 간격으로 전송이 된것을 보실 수 있습니다. 하지만 가끔씩  몇 시간에 한번만 트윗된 것도 보이실 겁니다. 이때는 테스트를 위해 실내에서 측정된 풍량/풍속/강수량 수치의 변화가 없어서 동일한 내용을 반복 포스팅한것으로 인지되어 무시된 경우입니다.  (계속 변화하는 시간값이나 랜덤숫자를 함께 전송하시면 이문제가 해결됩니다.)

사진. 기상측정 기구

+

사진. 아두이노로 만든 트위터 포스팅해주는 로봇

사용된 예제 소스 소개
값의 정밀도나 완성도를 무시하고 필요하신 분들에게 참고가 될 수 있도록 예제소스를 공개합니다.  풍향, 풍속, 강수량의 측정치 산정의 기준은 기상측정기기 제조사에서 제공한 데이타 시트를 참고하여 계산된 값입니다. 센서 연결 방법 및 기본 사용법 소개는 관련글 링크에 있는 글을 참고하시기 바랍니다.


/*
* 풍향, 풍속, 강수량을 Twitter에 포스팅하는 예제
  수정일시:  (2011.09.08a)  디버깅 및 기능개선을 위해 수시로 변경될 수 있습니다.

 풍향: 포스팅시 1회 계산 (16방위 중 하나로 측정)
 풍속: 20ms 주기로 10초간 모니터링 후 풍속계산
 강수량: 20ms 주기로 모니터링하여 1시간동안 누적(1시간에 1회 공식 데이타로 사용)
 
 핀연결
 풍향계: A0   풍향센서 전선 2개 중 하나는 GND에 나머지선은 A0에 연결 및 10k저항 거쳐 5V에 연결
 풍속계: D2   풍속센서 전선 2개 중 하나는 D2에 나머지는 GND
 강수계: D3   강수센서 전선 2개 중 하나는 D3에 나머지는 GND

 기타 핀 연결 (없어도 무방)
 D7: 풍속계 상태 LED
 D8: 강수량계 상태 LED
 D9: 버튼 ( 버튼을 누르면 10초내로 즉시 포스팅)

* http://ArtRobot.co.kr
* http://RoboBob.co.kr
*/

#include <SPI.h>
#include <Ethernet.h>
#include <EthernetDNS.h>
#include <Twitter.h>
#include <stdio.h>

#define WIND_N    0
#define WIND_NNE  22.5
#define WIND_NE    45
#define WIND_ENE  67.5
#define WIND_E    90
#define WIND_ESE  112.5
#define WIND_SE    135
#define WIND_SSE  157.5
#define WIND_S    180
#define WIND_SSW  202.5
#define WIND_SW   225
#define WIND_WSW  247.5
#define WIND_W    270
#define WIND_WNW  292.5
#define WIND_NW   315
#define WIND_NNW  337.5

// Ethernet Shield Settings
byte mac[] = { 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED }; //바꿔주세요

// substitute an address on your own network here
byte ip[] = { 192, 168, 100, 55 }; //바꿔주세요

// Your Token to Tweet (get it from http://arduino-tweet.appspot.com/)
Twitter twitter("발급받으신 토큰값을 적어주세요");  //바꿔주세요

// Message to post
char msg[100] = "";

const int windVanePin = A0;  // 풍량계 센서 입력핀
int windVaneValue = 0;        //
float windSpeed = 0;
float rainGauge = 0;
float windDirection = 0;
char windName[4];  // N (North)  S South,   NS(north south)   NNS(north north south) etc

  unsigned long windSpeedTimer;
  int windSpeedState = true;
  int windSpeedPin = 2;
  int windSpeedCounter = 0;
  unsigned long rainGaugeTimer;
  int rainGaugeState = true;
  int rainGaugePin = 3;
  int rainGaugeCounter = 0;
  int buttonState = true;
  int buttonPin = 9;
  int postTrigger = false;
  int postingCounter = 0;

void setup()
{
  delay(1000);
  Ethernet.begin(mac, ip);
  Serial.begin(9600);
 
  //wind speed sensor
  pinMode(windSpeedPin, INPUT);
  digitalWrite( windSpeedPin, HIGH);
 
  //rain gauge sensor
  pinMode(rainGaugePin, INPUT);
  digitalWrite( rainGaugePin, HIGH);

  //button for postMessge
  pinMode(buttonPin, INPUT);
  digitalWrite(buttonPin, HIGH);
 
  //wind speed sensor status LED
  pinMode(7, OUTPUT);
  digitalWrite(8,HIGH);
 
  //rain gauge status LED
  pinMode(8, OUTPUT);
  digitalWrite(8,HIGH);
 
}

// 문자배열변수값을 시리얼로 확인할경우만 사용
void printChars(char *msg, int len){
  if(len == 0) return;
  for(int i=0; i<len ; i++)
    Serial.print( msg[i]);
  Serial.println();
}

// sprintf함수에서 float형 print문제 대체용 함수 , float의 정수부인쇄
int f2h( float num){
  return int(num);
}

// sprintf함수에서 float형 print문제 대체용 함수 , float의 소수부인쇄
int f2p( float num){
  return (num - int(num)) * 100;
}


void loop()
{
  // 10초마다 샘플링 반복
  windSpeedTimer = millis() + 10000;
  windSpeedCounter = 0;
  while( millis() < windSpeedTimer ){
    delay(20); // 20ms 주기로 버튼이나 센서 스위칭 감시
    //wind speed
    if( (windSpeedState == true ) && !digitalRead( windSpeedPin) ){
        windSpeedCounter++;
        windSpeedState = false;
    }else if( (windSpeedState == false) && digitalRead(windSpeedPin) ){
        windSpeedState = true;
    }   
    //rain gauge
    if( (rainGaugeState == true ) && !digitalRead( rainGaugePin) ){
        rainGaugeCounter++;
        rainGaugeState = false;
    }else if( (rainGaugeState == false) && digitalRead(rainGaugePin) ){
        rainGaugeState = true;
    }       
   
    //button
    if( (buttonState == true ) && !digitalRead( buttonPin) ){
        postTrigger = true;
        buttonState = false;
    }else if( (buttonState == false) && digitalRead(buttonPin) ){
        buttonState = true;
    }      
    digitalWrite(7, windSpeedState);  
    digitalWrite(8, rainGaugeState);      
  }

  windSpeed = windSpeedCounter * 0.24;   // 1초당 1회 스위칭시 2.4km/h
  //Serial.print( "winSpeed: ");
  //Serial.println( windSpeed);

  rainGaugeTimer++;
  if( rainGaugeTimer > 360){  //1시간( 10 * 360 sec) 마다 postTrigger On
    rainGauge = rainGaugeCounter * 0.2794;
    rainGaugeCounter = 0;

관련글 링크

• 기상측정 기구 + 아두이노로 기상대 만들어요 (Arduino + Weather Sensor Assembly )
• 트위터(Twitter)에 자동 포스팅하는 기상관측 로봇 (현재글)
• 기상측정 트위터 로봇 - 실외 설치편
• 이더넷쉴드 관련   링크1   링크2

추가사항 (2011.11.29)
아두이노와 이더넷 쉴드를 하나로 결합한 Ethernet Pro 보드로 기상측정 트위터 기능을 구현할 수도 있습니다. 특히 PoE 케이블을 이용하시면 전원과 이더넷케이블을 하나로 줄일 수 있어 더욱편리합니다. 가령 위의 시스템을 아래의 이미지와 같이 간소화 시킬 수 있습니다.

안녕하세요 재밌는 창작재료가 너무 많아 무엇부터 갖고 놀아야 할지 고민이 됩니다.  ^^.  즐거운 고민이죠;;
오늘은 기상측정용 기구를 소개해 드리겠습니다.

참고로,

다음글

에서는 기상측정기구와 이더넷 연동되는 아두이노(Arduino)로 기상관측 자료를 트위터(Twitter)에 자동으로 올려주는 기특한 녀석을 소개시켜 드리겠습니다. 제법 시스템이라 불릴 만한 구성입니다.  바람의 방향과 속도 및 강수량을 측정할 수 있는 기상관측 기구로 부터 측정된 값을 모니터링하고 이를 곧바로 이더넷 쉴드가 장착된 아두이노로 트위터(twitter)에 올리는 것입니다.

일단은 기상측정기구에 대해 좀더 알아봅시다! 

Weather Meter (기상 관측기구 , Weather Sensor Assembly)
본 장비는 3가지 기상 관측 기초 자료를 측정할 수 있습니다.


1. Rain Gauge (강수량계)
입수되는 수량에 비례하여 스위칭을 해주는 특수 기구를 이용하여 1회 스위치시마다 0.2794mm 의 강수량에 대응되게 됩니다. 물시계 작동원리를 응용한것인데 아이디어가 참 좋네요

사진에는 안나왔네요;;  일단, 동영상을 참고하시길~

2. Anemometer (풍속계)
회전시마다 일정수의 스위칭이 이뤄지며 기준 시간당 스위칭 수를 측정하여 풍속 계산이 가능합니다. 1초 동안 1회 스위칭시 2.4km/h ( 0.6666m/s)의 속력에 대응합니다.

3. Wind Vane ( 풍향계)
바람의 방향을 16방위로 측정 가능한 센서입니다. 내장된 저항들과 회전각에 따라 작동되는 스위치에 의해 내부저항 값이 변화하며, 이 값을 10k옴 저항 한개와 기준전압 5V를 통해 아두이노 아나로그 입력 핀으로 감지하게 됩니다.  회전각에 따른 출력 전압 값은 데이타시트에 나와 있습니다.  ( 회로연결법은 매우 간단합니다.  광센서나 온도센서의 저항 변화를 전압변화로 출력해주는 회로와 동일)

그림1. 풍속계의 내부 회로도( 저항과 스위치 들이 보입니다. 스위치가 눌려지면 내부저항이 변화함)

그림2. 풍향계 연결법( 5V와 10k저항을 사용하면 아래의 테이블에 있는 전압값이 Output핀에 출력됩니다.)

가령 0도(North,정북)을 향할 경우 내부저항은 약 33k옴이고  이때 10k옴 저항과 5V에 연결시 약 3.84V 가 측정됩니다.

          
테이블1. 회전각/저항/전압 관계

참고. 제 경우 실측결과 315도 경우의 측정전압이 데이타시트와 달랐습니다. 참고하시기 바랍니다.


측정기의 비밀
본 장치를 회전시켜보면 풍향계와 풍속계 모두 매우 매끄럽게 회전됩니다. 센싱을 위해 스위치를 눌러주는 방식이라면 회전을 조금이라도 방해를 하게 될 테지만 이 기구는 그렇지 않습니다.  왜 그런지는 속을 들여다보면 나옵니다.  바로 마그네틱 센서입니다. 초소형 고강도 자석을 회전부에 설치해두고 회전시마다 자력으로 자석스위치를 일시적으로 단락시키는 방식을 사용하네요.  단순하고도 사용하기 편리한 메카니즘입니다.

연결 방법
풍향/풍속/강우량계 모두 각각의 케이블이 있으므로 총 3개의 케이블이 있습니다. 하지만 이중 풍속계 케이블을 풍향계 하단의 단자에 결합하게 되어 있으므로 2개의 케이블만 사용하면 됩니다.  케이블 전선은 일반 전화선과 유사하고 단자는 인터넷 케이블에 사용되는 것과 동일한 RJ45-8pin 단자입니다. 즉, 인터넷 케이블과 결합소켓을 이용하여 원하는 길이로 늘려줄 수 있게됩니다.  이더넷 케이블을 절단하여 라인을 브레드 보드에 결합하면 손쉽게 센서 스위치와 연결할 수 있습니다.(사진참조)
풍향계+풍속계 케이블 한곳에서 4개의 라인,  강수량계 케이블에서 2라인만 뽑아서 사용하면 됩니다.

측정 방법
풍속계와 강수량계는 스위치가 ON되는 횟수를 카운팅하면 되며 아두이노(Arduino)나 MCU를 이용하여 디지탈 입력핀으로 버튼이 눌려진 횟수를 카운팅하는 방법으로 측정이 가능합니다.  단, 스위칭시 노이즈로인해 1회 스위칭이 수~수십회 단락된 것으로 인지되므로 적절한 샘플링 주기(가령 20ms)마다 측정을 하여 스위치의 상태가 변이하는 순간에만 카운팅을 하도록 프로그램해줘야 합니다.  또한 강수량은 일정기간(가령 1시간)동안 그 값을 누적하여 결과로 사용하고,  풍속계도 일정 시간동안의 스위칭 횟수를 카운트하여 속력을 계산할 필요가 있습니다.
풍향 측정시엔 1개의 아날로그 입력핀이 필요하며, if else 구문으로 16 구간의 범위 조건으로 나눠서 각도를 구분해주면 됩니다. 


예제 소스
막상 어떻게 측정이 가능한지 궁굼하신 분들을 위해 참고용 소스코드를 함께 수록합니다.
정확성은 보장 못드리지만 참고하시기 바랍니다.

/*
 풍향, 풍속, 강수량 측정 예제
 
 풍향: 10초마다 1회 계산 (16방위 중 하나로 측정)
 풍속: 20ms 주기로 10초간 모니터링 후 풍속계산
 강수량: 20ms 주기로 모니터링하여 1시간동안 누적(1시간에 1회 공식 데이타로 사용)
 
 핀연결
 풍향계: A0   풍향센서 전선 2개 중 하나는 GND에 나머지선은 A0에 연결 및 10k저항 거쳐 5V에 연결
 풍속계: D2   풍속센서 전선 2개 중 하나는 D2에 나머지는 GND
 강수계: D3   강수센서 전선 2개 중 하나는 D3에 나머지는 GND
 
 http://ArtRobot.co.kr
 http://RoboBob.co.kr
*/


#define WIND_N    0 //정 북향
#define WIND_NNE  22.5
#define WIND_NE    45
#define WIND_ENE  67.5
#define WIND_E    90  //정 동향
#define WIND_ESE  112.5
#define WIND_SE    135
#define WIND_SSE  157.5
#define WIND_S    180
#define WIND_SSW  202.5
#define WIND_SW   225
#define WIND_WSW  247.5
#define WIND_W    270
#define WIND_WNW  292.5
#define WIND_NW   315
#define WIND_NNW  337.5


// Message to post
char msg[100] = "";

const int windVanePin = A0;  // 아날로그 0번핀에 연결
int winVaneValue = 0;        //
float windSpeed = 0;
float rainGauge = 0;
float windDirection = 0;
char windName[4];  // N (North)  S South,   NS(north south)   NNS(north north south)

  unsigned long windSpeedTimer;
  int windSpeedState = true;
  int windSpeedPin = 2;
  int windSpeedCounter = 0;
  unsigned long rainGaugeTimer;
  int rainGaugeState = true;
  int rainGaugePin = 3;
  int rainGaugeCounter = 0;


void setup()
{

  Serial.begin(9600);
 
  //wind speed sensor
  pinMode(windSpeedPin, INPUT);
  digitalWrite( windSpeedPin, HIGH);
 
  //rain gauge sensor
  pinMode(rainGaugePin, INPUT);
  digitalWrite( rainGaugePin, HIGH);
 
}

/*
* char 배열의 문자열정보를 Serial통해 문자로 전송 ,  PC에서 참고용
* char 배열을 사용한것은 차후 인터넷통신(트위터전송)을 위한 것입니다.
*/
void printChars(char *msg, int len){
  if(len == 0) return;
  for(int i=0; i<len ; i++)
    Serial.print( msg[i]);
  Serial.println();
}

/*
* f2h와 f2p는  float형의 정수부와 소수부를 위한 것입니다.
* sprintf에서 float형 사용에 문제가 있어서 땜빵으로 사용된 함수입니다.
*/
int f2h( float num){
  return int(num);
}

int f2p( float num){
  return (num - int(num)) * 100;
}


void loop()
{
  // 10초마다 측정결과를 PC에 전달

  windSpeedTimer = millis() + 10000; // 10초를 주기로 반복됩니다.
  windSpeedCounter = 0;
  while( millis() < windSpeedTimer ){
    delay(20); //20ms 주기로 센서의 스위칭을 감지합니다.
    //wind speed  풍속계 센서 감지부
    if( (windSpeedState == true ) && !digitalRead( windSpeedPin) ){
        windSpeedCounter++;     //스위치 상태가 high에서 low로 떨어지는 순간을 감지합니다.
        windSpeedState = false;
    }else if( (windSpeedState == false) && digitalRead(windSpeedPin) ){
        windSpeedState = true;
    }   
    //rain gauge
    if( (rainGaugeState == true ) && !digitalRead( rainGaugePin) ){
        rainGaugeCounter++;     //스위치 상태가 high에서 low로 떨어지는 순간을 감지합니다.
        rainGaugeState = false;
    }else if( (rainGaugeState == false) && digitalRead(rainGaugePin) ){
        rainGaugeState = true;
    }       
  }
 
  rainGaugeTimer++;
 
  if( rainGaugeTimer > 360){// 10초 * 360 = 3600초(1시간)  지난 1시간동안 누적한 강수계 카운터로 강수량 계산
    rainGauge = rainGaugeCounter * 0.2794;
    rainGaugeCounter = 0;
    rainGaugeTimer = 0;
  }
  
    windSpeed = windSpeedCounter * 0.24 ;   // 1초당 1회 스위칭시 2.4km/h 속력이며 10초 기간이므로 0.24가 됨
    getWindDirection();  // 풍향은 발표시점에 1회만 측정
   
    //char 배열에 정보를 취합(인터넷 전송에 적합한 자료형)
    sprintf( msg, "ArtRobot's Weather Bot said => Wind: %s/%d.%d, %d.%d(km/h) Rain %d.%d(mm/h).", windName, f2h(windDirection), f2p(windDirection), f2h(windSpeed), f2p(windSpeed),  f2h(rainGauge), f2p(rainGauge) );
    printChars( msg, sizeof(msg) ); //PC에서 참고용으로 시리얼전송
    //이후 소개할 예제에서 위 자료를 이더넷을 통해 트위터에 포스팅하게됨
 
}


/*
* 풍향측정: 아날로그핀입력되는 전압값으로 16가지 방향중 하나로 계산됨.
*
*/
float getWindDirection(void){
  int readValue = analogRead(windVanePin);           
  // 0~1023 사이의 입력값을 0~5V 기준 값으로 비례변경함.
  winVaneValue = map(readValue, 0, 1023, 0, 500);   
  //이제 winVaneValue는 데이타 시트정보상의 방위별 전압치와 유사한 값이 됩니다.
 
  if( winVaneValue < 35){
    //0~0.35V를 동동서 로 인식함
    //   112.5  0.32v (31 32)    0~35
    windDirection = WIND_ESE;
    strcpy(windName ,"ESE");       
  }else if( winVaneValue < 43 ){
    //   67.5  0.41v(40 41)    ~42   
    windDirection = WIND_ENE;
    strcpy(windName , "ENE");       
  }else if( winVaneValue < 50 ){
    //   90  0.45v(44 45)      ~50   
    windDirection = WIND_E;
    strcpy(windName , "E");       
  }else if( winVaneValue < 70 ){
    //   157.5  0.62v(60 62)   ~70
    windDirection = WIND_SSE;
    strcpy(windName , "SSE");       
  }else if( winVaneValue < 100 ){
    //   135  0.90v(89 90)      ~100
    windDirection = WIND_SE; 
    strcpy(windName , "SE");       
  }else if( winVaneValue < 130 ){
    //   202.5  1.19v(119 120)  ~130
    windDirection = WIND_SSW; 
    strcpy(windName , "SSW");       
  }else if( winVaneValue < 170 ){
    //   180  1.40v(140 141)   ~170
    windDirection = WIND_S; 
    strcpy(windName , "S");       
  }else if( winVaneValue < 210 ){
    //   22.5  1.98v(198 199)  ~210
    windDirection = WIND_NNE; 
    strcpy(windName , "NNE");           
  }else if( winVaneValue < 250 ){
    //   45  2.25v(226 227)    ~250
    windDirection = WIND_NE; 
    strcpy(windName , "NE");           
  }else if( winVaneValue < 300 ){
    //  247.5  2.93v(293 294)  ~300
    windDirection = WIND_WSW; 
    strcpy(windName , "WSW");       
  }else if( winVaneValue < 320 ){
    //  225  3.08v(308 310)   ~320
    windDirection = WIND_SW; 
    strcpy(windName , "SW");       
  }else if( winVaneValue < 360 ){
    //  337.5  3.43 (343 345)  ~360
    windDirection = WIND_NNW; 
    strcpy(windName , "NNW");       
  }else if( winVaneValue < 395 ){
    //   0  3.84v(384~385)    ~395
    windDirection = WIND_N; 
    strcpy(windName , "N");
  }else if( winVaneValue < 415 ){
    //  292.5  4.04v(405 406)  ~415
    windDirection = WIND_WNW; 
    strcpy(windName , "WNW");   
  }else if( winVaneValue < 450 ){
    //  315  4.34(433 434)  ~450
    windDirection = WIND_NW; 
    strcpy(windName , "NW");       
  }else if( winVaneValue < 490 ){
    //  270  4.62v(461 463)    ~490
    windDirection = WIND_W; 
    strcpy(windName , "W");       
  }else{
   //error  알수없는 값범위
  }

}


결과 출력예
위 예제의 경우 10초마다 아래와 같은 결과가 PC로 전송됩니다.
ArtRobot's Weather Bot said => Wind: N/0.0, 3.83(km/h) Rain 0.0(mm/h).
ArtRobot's Weather Bot said => Wind: W/270.0, 4.79(km/h) Rain 0.0(mm/h).
...



관련제품 링크
 

기상측정기구(Weather Meter)

아두이노 UNO(Arduino)

연관글 보러 바로가기
 

트위터(Twitter)에 기상측정 자료 올려주는 로봇 만들기